home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
CD ROM Paradise Collection 4
/
CD ROM Paradise Collection 4 1995 Nov.iso
/
database
/
sigrea.zip
/
SIGREADR.CH
< prev
next >
Wrap
Text File
|
1994-04-12
|
4KB
|
75 lines
//****************************************************************
//* Program Name: sigreadr.ch *
//* Author: Stan Grossman *
//* Copyright (c) 1993 by SIG Software *
//* 9074 Andromeda Drive *
//* Burke, VA 22015 *
//* 703-455-6814 *
//* *
//*---------------------------- ALL RIGHTS RESERVED -------------*
//****************************************************************
// SIG additions to GETSYS
//
// Uses replacement reader in SIGREADR.OBJ
//───── RIGHT clause addition (right justifies char entry)
#xcommand @ <row>, <col> SIGGET <var> RIGHT ;
[PICTURE <pic>] ;
[VALID <valid>] ;
[WHEN <when>] ;
[MESSAGE <message>] ;
[COLOR <color>] ;
;
=> SetPos( <row>, <col> ) ;
; AAdd( ;
GetList, ;
_GET_( <var>, <(var)>, <pic>, <{valid}>, <{when}>) ;
) ; ;
ATail(GetList):reader := { | g | sigReader(g, ;
{ | get, key | sigKeyRight(get, key) } ) } ;
[ ; Atail(GetList):colorDisp( <color> )] ;
[ ; Atail(GetList):cargo := { <message>, "RIGHT" } ]
//───── MEMO clause addition (does memoedit)
#xcommand @ <row>, <col> SIGGET <var> MEMO <len>, <lines> ;
[WHEN <when>] ;
[COLOR <color>] ;
[<nostamp:NOSTAMP>] ;
;
=> SetPos( <row>, <col> ) ;
; sigMakeMemoGet( <row>, <col>, <"var">, <len>, <lines> ) ;
[ ; Atail(GetList):preBlock := <{when}> ] ;
[ ; Atail(GetList):colorDisp( <color> )] ;
[ ; Aadd(Atail(GetList):cargo,#<nostamp> )] ;
; sigMemoDisp(ATail(GetList))
//───── MEMO clause addition for display only (does memoedit with no edit)
#xcommand @ <row>, <col> SIGSAY <var> MEMO <len>, <lines> ;
[COLOR <color>] ;
;
=> SetPos( <row>, <col> ) ;
; sigMemoSay( <row>, <col>, <"var">, <len>, <lines> [, <color>] )
//───── LOGICAL clause addition (displays Yes/No)
#xcommand @ <row>, <col> SIGGET <var> LOGICAL ;
[WHEN <when>] ;
[VALID <valid>] ;
[COLOR <color>] ;
;
=> SetPos( <row>, <col> ) ;
; AAdd( ;
GetList, ;
_GET_( <var>, <(var)>, "Y", <{valid}>, <{when}>) ;
) ; ;
ATail(GetList):reader := { | g | sigReader(g, ;
{ | get, key | sigKeyLogical(get, key) } ) } ;
[ ; Atail(GetList):colorDisp( <color> )] ;
; Atail(GetList):cargo := { "", "LOGICAL" } ;
; sigDispLogical()